By Karl Voelker

Perl is well-known for its vast collection of modules called CPAN at http://www.cpan.org/.

You can install modules from CPAN by running cpan as root on a UNIX-like system with Perl.

You include a module with use.

A use statement may include a list of module subroutines to import.

We can't cover every Perl module, so we'll just cover the ones I find most useful:

Use Carp to:

Obtain a printable stack trace:

Carp::longmess

When writing a module, deal with errors that aren't your fault:

• Carp::carp (like warn)
• Carp::croak (like die)

The CGI module is for writing web applications with the Common Gateway Interface.

use CGI qw/header param/;

print header(-type => 'text/plain');
print "Hello, ", param('name'), "!\n";

Data::Dumper prints data structures as valid Perl:

use Data::Dumper;

print Dumper(
	{'foo' => [1, 2, 3], 
	 'bar' => {'baz' => 4, 
		   'quux' => 5}});

Date::Calc makes math with dates easy.

use Date::Calc qw/Delta_Days Today/;

my $delta = Delta_Days(
		Today, 2008, 12, 25);
print "$delta days until Christmas!\n";

Device::ParallelPort makes programming for a parallel port fun (on Linux or Windows)!

use Device::ParallelPort::drv::linux;

my $port = Device::ParallelPort->new;
foreach my $bit (0..7) {
	$port->set_bit($bit, 1);
	sleep 1;
	$port->set_bit($bit, 0);
}

Digest::SHA calculates SHA hashes with ease!

use Digest::SHA qw/sha512_hex/;

print sha512_hex("secret password");

DBI provides a standard interface to any relational database.

use DBI;

my $dbh = DBI->connect("DBI:mysql:$db", 
	$user, $pass);
my $sth = $dbh->prepare('SELECT * 
	FROM cheese WHERE age > ?');
$sth->execute(10);
my $res = $sth->fetchall_arrayref({});

Exporter lets a module make functions available for other modules to import.

package Foo;
use base qw/Exporter/;
our @EXPORT_OK = qw/bar/;
sub bar { print "Hello, World!\n"; }

package Baz;
use Foo qw/bar/;
bar();

File::Temp can safely open a temporary file.

use File::Temp qw/tempfile/;

my ($fh, $filename) = tempfile;
print $fh "This file is $filename.\n";

close $fh;

Getopt::Std parses command-line arguments for switches.

use Getopt::Std qw/getopts/;

getopts('hv:', \%opt);
if ($opt{'h'}) {
    print "You asked for help.\n";
} else {
    print "Verbosity: $opt{'v'}.\n";
}

IO::Socket::INET makes network communication easy.

use IO::Socket::INET;

my $sock = IO::Socket::INET->new(
	'PeerHost' => 'foo.net', 
	'PeerPort' => 1111, 
	'Proto' => 'tcp');
print $sock "Foo\n";
print <$sock>;
$sock->close;

IPC::Open2 runs a process and gives you two-way communication with it.

use IPC::Open2;

open2($out, $in, 'bc');
print $out "3 * 4\n";
my $twelve = <$in>;
print $out "quit\n";
print $twelve;

List::Util provides utility functions for lists.

use List::Util qw/reduce shuffle/;

my @list = (1, 2, 3, 4);
my $sum = reduce { $a + $b } @list;

my @cards = shuffle 0..51;

LWP::UserAgent enables browsing the web, even sites that use cookies.

use LWP::UserAgent;
my $ua = LWP::UserAgent->new;
my $response = 
    $ua->get('http://www.google.com/');
if ($response->is_success) {
    print $response->content;
} else {
    die $response->status_line;
}

Mail::Sendmail lets you send electronic mail.

use Mail::Sendmail;

sendmail(
    'To'      => 'me@karlv.net', 
    'From'    => 'perl@karlv.net', 
    'Subject' => 'Testing', 
    'Message' => "Hello, World!\n");

Net::Server is a family of modules that provide simple, forking, and multiplexing server daemons.

package Echo::Server;
use base qw/Net::Server/;

sub process_request {
    print while <>;
}

__PACKAGE__->run('port' => 4242);

Time::HiRes lets you measure time with microsecond resolution.

use Time::HiRes /gettimeofday usleep/;

my ($sec, $usec) = gettimeofday;

usleep 1000000;

Questions?